prefix skos:   <http://www.w3.org/2004/02/skos/core#>
prefix dct:    <http://purl.org/dc/terms/>
prefix xsd:    <http://www.w3.org/2001/XMLSchema#>

PREFIX rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>

prefix dbc:    <http://dbpedia.org/resource/Category:>
prefix dbr:    <http://dbpedia.org/resource/>
prefix dbp:    <http://dbpedia.org/property/>

PREFIX dbo:    <http://dbpedia.org/ontology/>

PREFIX prov:   <http://www.w3.org/ns/prov#>

SELECT ?country_in_year (?year AS ?Year) (?country AS ?Country) ?entrant ?song

WHERE {
  SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {
    ?countries_in_esc_by_year skos:broader dbc:Countries_in_the_Eurovision_Song_Contest_by_year.

    ?country_in_year dct:subject ?countries_in_esc_by_year.
    bind( REPLACE(str(?country_in_year), ".*(\\d{4})", "$1") as ?year).
    FILTER ( xsd:integer(?year) < 2020).

    ?country_in_year dbp:country ?country.

    ?country_in_year dbp:entrant ?entrant
        FILTER (isURI(?entrant)).    

    ?country_in_year dbp:song ?song_errata
       FILTER (isLITERAL(?song_errata)).
  }

  ?country_in_year dbp:song ?song.
  ?country_in_year dct:source ?song_errata.

  SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {
    ?song dbp:artist|dbp:as ?entrant. 
  }

  ?song dct:source ?song_errata.

  OPTIONAL {
    SERVICE <https://dbpedia.demo.openlinksw.com/sparql> {
      ?entrant rdfs:label ?entrant_label
        FILTER (lang(?entrant_label) = 'en').
    }
  }
}
ORDER BY DESC(?countries_in_esc_by_year)