@echo off

echo.
echo Greenstone 3 (GSDL3)
echo Copyright (C) 2004 New Zealand Digital Libraries, University Of Waikato
echo Greenstone 3 comes with ABSOLUTELY NO WARRANTY; for details see LICENSE.txt
echo This is free software, and you are welcome to redistribute it
echo.

::  -------- Launch the Greenstone 3 Digital Library Software --------

if exist gs3-setup.bat goto begin
  echo This script must be run from within the Greenstone 3 home directory
  pause
  goto exit

:begin
:: ---- Run setup.bat to set the necessary environment variables ----
call gs3-setup.bat
echo.

:: Set up java options for catalina
set CATALINA_HOME=%GSDL3HOME%\comms\jakarta\tomcat
set CATALINA_OPTS="-Djava.util.prefs.syncInterval=2000000 -DGSDL3HOME=%GSDL3HOME% -DGSDLOS=%GSDLOS% -DPATH=%PATH%"

if ""%1"" == ""-shutdown"" goto shutdown
    ::  -------- Run MySQL --------
    echo Starting MySQL server...
    echo.
    cd %GSDL3HOME%\packages\mysql
    start bin\mysqld
    cd %GSDL3HOME%
    echo Done.

    ::  -------- Run Tomcat --------
    echo Starting Tomcat Webserver...
    echo.
    call "%GSDL3HOME%\comms\jakarta\tomcat\bin\startup.bat"
    echo Done.

    :: ---- Launch a web browser ----
    start http://localhost:8080/gsdl3
    goto exit

:shutdown
    :: -------- Stop Tomcat --------
    echo Shutting down Tomcat Webserver...
    echo.
    call "%GSDL3HOME%\comms\jakarta\tomcat\bin\shutdown.bat"
    echo Done.

    :: -------- Stop MySQL --------
    echo Stopping MySQL server...
    echo.
    cd %GSDL3HOME%\packages\mysql
    bin\mysqladmin --user=root shutdown
    cd %GSDL3HOME%
    echo Done.

    echo ****************************************************************
    echo  Greenstone 3 has been shutdown. Run gs3-launch.bat to restart.
    echo ****************************************************************

:exit