source: other-projects/expeditee-release-kits/trunk/create-expeditee.bat@ 37978

@echo off
setlocal

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-us
for /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%b-%%a)
echo The current date is %mydate%


:: installdir (C:\expeditee\expeditee-release-kits)
set installdir=C:\expeditee\expeditee-release-kits
cd %installdir%

:: Need to edit rke-setup.bat and fill it in with local env vars values
if not exist %installdir%\rke-setup.bat (
echo. 
echo ******************* 
echo. 
echo First generate %installdir%\rke-setup.bat by copying
echo %installdir%\rke-setup.bat.in and editing it for your environment
echo. 
echo ******************* 
echo. 
goto end
)

:: call rke-setup.bat to set the environment vars expeditee RK needs
call rke-setup.bat
if ERRORLEVEL 1 (
    echo error level 1 or more  
    exit /B 1
)


:: Make sure the expeditee folder and its rke-build.properties file exist
:: Then run the 'rke' command from snapshots\expeditee
pushd %installdir%\snapshots
::http://www.robvanderwoude.com/battech_ifexistfolder.php
if exist expeditee\ echo Deleting snapshots\expeditee&& rmdir /s /q expeditee
if not exist expeditee\ mkdir expeditee
if not exist expeditee\rke-build.properties copy %installdir%\rke-build.properties.in expeditee\rke-build.properties
pushd expeditee
echo About to call rke
call rke


echo rke done
echo Getting uploads ready
:: Uploading
mkdir uploads
copy products\Expeditee-1%products_suffix%.exe uploads\Expeditee-1-%mydate%%uploads_suffix%.exe
copy rke.out uploads\rke-%mydate%%os_suffix%-windows.out

:: For now, we are uploading to www-internal. authorised_keys at that end will untar into /greenstone/files/expeditee
cd uploads && tar.exe -c * | plink -T -i "%identity_file%" [email protected]
:end

cd %installdir%
endlocal
::exit