root/trunk/gsdl/perllib/plugins/PDFPlug.pm @ 10889

Revision 10889, 11.5 KB (checked in by kjdon, 14 years ago)

added a description to metadata_fields arg, also retabbed the argument list

  • Property svn:keywords set to Author Date Id Revision
Line 
1###########################################################################
2#
3# PDFPlug.pm -- reasonably with-it pdf plugin
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999-2001 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25package PDFPlug;
26
27use ConvertToPlug;
28use unicode;
29use strict;
30no strict 'refs'; # so we can use a var for filehandles (eg STDERR)
31
32sub BEGIN {
33    @PDFPlug::ISA = ('ConvertToPlug');
34}
35
36my $convert_to_list =
37    [ { 'name' => "auto",
38    'desc' => "{ConvertToPlug.convert_to.auto}" },
39      { 'name' => "html",
40    'desc' => "{ConvertToPlug.convert_to.html}" },
41      { 'name' => "text",
42    'desc' => "{ConvertToPlug.convert_to.text}" },
43      { 'name' => "pagedimg_jpg",
44    'desc' => "{ConvertToPlug.convert_to.pagedimg_jpg}"},
45      { 'name' => "pagedimg_gif",
46    'desc' => "{ConvertToPlug.convert_to.pagedimg_gif}"},
47      { 'name' => "pagedimg_png",
48    'desc' => "{ConvertToPlug.convert_to.pagedimg_png}"},
49      ];
50
51
52my $arguments =
53    [
54     { 'name' => "convert_to",
55       'desc' => "{ConvertToPlug.convert_to}",
56       'type' => "enum",
57       'reqd' => "yes",
58       'list' => $convert_to_list,
59       'deft' => "html" },   
60     { 'name' => "process_exp",
61       'desc' => "{BasPlug.process_exp}",
62       'type' => "regexp",
63       'deft' => &get_default_process_exp(),
64       'reqd' => "no" },
65     { 'name' => "block_exp",
66       'desc' => "{BasPlug.block_exp}",
67       'type' => "regexp",
68       'deft' => &get_default_block_exp() },
69     { 'name' => "metadata_fields",
70       'desc' => "{HTMLPlug.metadata_fields}",
71       'type' => "string",
72       'deft' => "" },
73     { 'name' => "noimages",
74       'desc' => "{PDFPlug.noimages}",
75       'type' => "flag" },
76     { 'name' => "allowimagesonly",
77       'desc' => "{PDFPlug.allowimagesonly}",
78       'type' => "flag" },
79     { 'name' => "complex",
80       'desc' => "{PDFPlug.complex}",
81       'type' => "flag" },
82     { 'name' => "nohidden",
83       'desc' => "{PDFPlug.nohidden}",
84       'type' => "flag" },
85     { 'name' => "zoom",
86       'desc' => "{PDFPlug.zoom}",
87       'deft' => "2",
88       'range' => "1,3", # actually the range is 0.5-3
89       'type' => "int" },
90     { 'name' => "use_sections",
91       'desc' => "{PDFPlug.use_sections}",
92       'type' => "flag" },
93     { 'name' => "description_tags",
94       'desc' => "{HTMLPlug.description_tags}",
95       'type' => "flag" }
96     ];
97
98my $options = { 'name'     => "PDFPlug",
99        'desc'     => "{PDFPlug.desc}",
100        'abstract' => "no",
101        'inherits' => "yes",
102        'args'     => $arguments };
103
104sub new {
105    my ($class) = shift (@_);
106    my ($pluginlist,$inputargs,$hashArgOptLists) = @_;
107    push(@$pluginlist, $class);
108
109    push(@$inputargs,"-title_sub");
110    push(@$inputargs,'^(Page\s+\d+)?(\s*1\s+)?');
111
112    if(defined $arguments){ push(@{$hashArgOptLists->{"ArgList"}},@{$arguments});}
113    if(defined $options) { push(@{$hashArgOptLists->{"OptList"}},$options)};
114
115    my @arg_array = @$inputargs;
116    my $self = (defined $hashArgOptLists)? new ConvertToPlug($pluginlist,$inputargs,$hashArgOptLists): new ConvertToPlug($pluginlist,$inputargs);
117   
118    if ($self->{'info_only'}) {
119    # don't worry about any options etc
120    return bless $self, $class;
121    }
122
123    # these are passed through to gsConvert.pl by ConvertToPlug.pm
124    my $zoom = $self->{"zoom"};
125    $self->{'convert_options'} = "-pdf_zoom $zoom";
126    $self->{'convert_options'} .= " -pdf_complex" if $self->{"complex"};
127    $self->{'convert_options'} .= " -pdf_nohidden" if $self->{"nohidden"};
128    $self->{'convert_options'} .= " -pdf_ignore_images" if $self->{"noimages"};
129    $self->{'convert_options'} .= " -pdf_allow_images_only" if $self->{"allowimagesonly"};
130
131    my $secondary_plugin_options = $self->{'secondary_plugin_options'};
132
133    if (!defined $secondary_plugin_options->{'HTMLPlug'}) {
134    $secondary_plugin_options->{'HTMLPlug'} = [];
135    }
136    if (!defined $secondary_plugin_options->{'TEXTPlug'}) {
137    $secondary_plugin_options->{'TEXTPlug'} = [];
138    }
139    if (defined $self->{'convert_to'} && $self->{'convert_to'} =~ /pagedimg.*/i) {
140    if (!defined $secondary_plugin_options->{'PagedImgPlug'}){
141        $secondary_plugin_options->{'PagedImgPlug'} = [];
142        my $pagedimg_options = $secondary_plugin_options->{'PagedImgPlug'};
143        push(@$pagedimg_options, "-title_sub", '^(Page\s+\d+)?(\s*1\s+)?');
144    }
145    }
146    my $html_options = $secondary_plugin_options->{'HTMLPlug'};
147    my $text_options = $secondary_plugin_options->{'TEXTPlug'};
148   
149    if ($self->{'input_encoding'} eq "auto") {
150    # pdftohtml will always produce html files encoded as utf-8
151    # => restrict primary PDFPlug and secondary HTML plugin to use
152    # utf8 and extract language.
153    $self->{'input_encoding'} = "utf8";
154    $self->{'extract_language'} = 1;
155
156    push(@$html_options,"-extract_language");
157    }
158    # if pdftohtml is always producing utf8, then htmlplug always needs this option
159    push(@$html_options,"-input_encoding", "utf8");
160
161    # Instruct HTMLPlug (when eventually accessed through read_into_doc_obj)
162    # to extract these metadata fields from the HEAD META fields
163    my $required_metadata;
164    if (defined $self->{'metadata_fields'} && $self->{'metadata_fields'} =~ /\S/) {
165    push(@$html_options,"-metadata_fields",$self->{'metadata_fields'});
166    } else {
167    push(@$html_options,"-metadata_fields","Title,GENERATOR,date,author<Creator>");
168    }
169    #push(@$html_options,"-metadata_fields","Title,GENERATOR,date,author<Creator>");
170       
171    if ($self->{'use_sections'} || $self->{'description_tags'}) {
172    $self->{'description_tags'} = 1;
173    push(@$html_options,"-description_tags");
174    }
175
176    # following title_sub removes "Page 1" added by pdftohtml, and a leading
177    # "1", which is often the page number at the top of the page. Bad Luck
178    # if your document title actually starts with "1 " - is there a better way?
179    push(@$html_options , "-title_sub", '^(Page\s+\d+)?(\s*1\s+)?');
180    push(@$text_options , "-title_sub", '^(Page\s+\d+)?(\s*1\s+)?');
181 
182    $self = bless $self, $class;
183    $self->load_secondary_plugins($class,$secondary_plugin_options,$hashArgOptLists);
184    return $self;
185}
186
187sub get_default_process_exp {
188    my $self = shift (@_);
189
190    return q^(?i)\.pdf$^;
191}
192
193# so we don't inherit HTMLPlug's block exp...
194sub get_default_block_exp {
195    return "";
196}
197   
198sub convert_post_process
199{
200    my $self = shift (@_);
201    my ($conv_filename) = @_;
202
203    my $outhandle=$self->{'outhandle'};
204
205    my ($language, $encoding) = $self->textcat_get_language_encoding ($conv_filename);
206
207    # read in file ($text will be in utf8)
208    my $text = "";
209    $self->read_file ($conv_filename, $encoding, $language, \$text);
210
211    # Calculate number of pages based on <a ...> tags (we have a <a name=1> etc
212    # for each page).  Metadata based on this calculation not set until process()
213    #
214    # Note: this is done even if we are not breaking to document into pages as it might
215    # be useful to give an indication of document length in browser through setting
216    # num_pages as metadata.
217    my @pages = ($text =~ /\<[Aa] name=\"?\w+\"?>/ig);
218    my $num_pages = scalar(@pages);
219    $self->{'num_pages'} = $num_pages;
220
221    if ($self->{'use_sections'}
222    && $self->{'converted_to'} eq "HTML") {
223
224    print $outhandle "PDFPlug: Calculating sections...\n";
225
226    # we have "<a name=1></a>" etc for each page
227    # it may be <A name=
228    my @sections = split('<[Aa] name=', $text);
229
230    my $top_section = "";
231
232    if (scalar (@sections) == 1) { #only one section - no split!
233        print $outhandle "PDFPlug: warning - no sections found\n";
234    } else {
235        $top_section .= shift @sections; # keep HTML header etc as top_section
236    }
237
238    # handle first section specially for title? Or all use first 100...
239   
240    my $title = $sections[0];
241    $title =~ s/^\"?\w+\"?>//; # specific for pdftohtml...
242    $title =~ s/<\/([^>]+)><\1>//g; # (eg) </b><b> - no space
243    $title =~ s/<[^>]*>/ /g;
244    $title =~ s/(?:&nbsp;|\xc2\xa0)/ /g; # utf-8 for nbsp...
245    $title =~ s/^\s+//s;
246    $title =~ s/\s+$//;
247    $title =~ s/\s+/ /gs;
248    $title =~ s/^$self->{'title_sub'}// if ($self->{'title_sub'});
249    $title =~ s/^\s+//s; # in case title_sub introduced any...
250    $title = substr ($title, 0, 100);
251    $title =~ s/\s\S*$/.../;
252
253
254    if (scalar (@sections) == 1) { # no sections found
255        $top_section .= $sections[0];
256        @sections=();
257    } else {
258        $top_section .= "<!--<Section>\n<Metadata name=\"Title\">$title</Metadata>\n-->\n <!--</Section>-->\n";
259    }
260
261    # add metadata per section...
262    foreach my $section (@sections) {
263        # section names are not always just digits, may be like "outline"
264        $section =~ s@^\"?(\w+)\"?></a>@@; # leftover from split expression...
265
266        $title = $1; # Greenstone does magic if sections are titled digits
267        if (! defined($title) ) {
268        print STDERR "no title: $section\n";
269        $title = " "; # get rid of the undefined warning in next line
270        }
271        my $newsection = "<!-- from PDFPlug -->\n<!-- <Section>\n";
272        $newsection .= "<Metadata name=\"Title\">" . $title
273        . "</Metadata>\n--><p>\n";
274        $newsection .= $section;
275        $newsection .= "<!--</Section>-->\n";
276        $section = $newsection;
277    }
278
279    $text=join('', ($top_section, @sections));
280    }
281
282    # turn any high bytes that aren't valid utf-8 into utf-8.
283    unicode::ensure_utf8(\$text);
284
285    # Write it out again!
286    $self->utf8_write_file (\$text, $conv_filename);
287}
288
289
290# do plugin specific processing of doc_obj for HTML type
291sub process {
292    my $self = shift (@_);
293    my ($textref, $pluginfo, $base_dir, $file, $metadata, $doc_obj, $gli) = @_;
294
295    my $result = $self->process_type("pdf",$base_dir,$file,$doc_obj);
296
297    # fix up the extracted date metadata to be in Greenstone date format,
298    # and fix the capitalisation of 'date'
299    my $cursection = $doc_obj->get_top_section();
300    foreach my $datemeta (@{$doc_obj->get_metadata($cursection, "date")}) {
301    $doc_obj->delete_metadata($cursection, "date", $datemeta);
302
303    # We're just interested in the date bit, not the time
304    # some pdf creators (eg "Acrobat 5.0 Scan Plug-in for Windows")
305    # set a /CreationDate, and set /ModDate to 000000000. pdftohtml
306    # extracts the ModDate, so it is 0...
307    $datemeta =~ /(\d+)-(\d+)-(\d+)/;
308    my ($year, $month, $day) = ($1,$2,$3);
309    if (defined($year) && defined($month) && defined($day)) {
310        if ($year == 0) {next}
311        if ($year < 100) {$year += 1900} # just to be safe
312        if ($month =~ /^\d$/) {$month="0$month"} # single digit
313        if ($day =~ /^\d$/) {$day="0$day"} # single digit
314        my $date="$year$month$day";
315        $doc_obj->add_utf8_metadata($cursection, "Date", $date);
316    }
317    }
318
319    $doc_obj->add_utf8_metadata($cursection, "NumPages", $self->{'num_pages'});
320   
321    if ($self->{'use_sections'} && $self->{'converted_to'} eq "HTML") {
322    # we explicitly make it a paged document, cos greenstone won't get it
323    # right if any section has an empty title, or one with letters in it
324    $doc_obj->set_utf8_metadata_element ($cursection, "gsdlthistype", "Paged");
325    }
326
327    return $result;
328}
329
3301;
Note: See TracBrowser for help on using the browser.