source: trunk/gsdl3/bin/script/convert_coll_from_gs2.pl@ 12979

Last change on this file since 12979 was 12979, checked in by kjdon, 18 years ago

if SearchVLIst not there, then look for a VLIst and output that as the search format
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 20.5 KB
Line 
1#!/usr/bin/perl -w
2
3BEGIN {
4 die "GSDLHOME not set\n" unless defined $ENV{'GSDLHOME'};
5 die "GSDL3HOME not set\n" unless defined $ENV{'GSDL3HOME'};
6 die "GSDL3SRCHOME not set\n" unless defined $ENV{'GSDL3SRCHOME'};
7 die "GSDLOS not set\n" unless defined $ENV{'GSDLOS'};
8 unshift (@INC, "$ENV{'GSDLHOME'}/perllib");
9 unshift (@INC, "$ENV{'GSDL3SRCHOME'}/lib/perl/cpan");
10}
11
12use colcfg;
13use util;
14use parsargv;
15use FileHandle;
16use XML::Writer;
17#can't get this to work on windows
18#use GDBM_File;
19
20use strict;
21
22&main();
23sub print_usage() {
24 print STDOUT "Usage: convert_coll_from_gs2.pl [options] coll-name\n";
25 print STDOUT "options:\n";
26
27 print STDOUT " -collectdir Directory where collection lives.\n";
28 print STDOUT " -verbosity Controls the amount of output.\n";
29 print STDOUT " -defaultlang The language that is considered the default (for display text etc). defaults to 'en'\n\n";
30}
31
32sub main {
33
34 my ($defaultlang, $verbosity, $collectdir);
35 # note that no defaults are passed for most options as they're set
36 # later (after we check the collect.cfg file)
37 if (!&parsargv::parse(\@ARGV,
38 'verbosity/\d+/', \$verbosity,
39 'collectdir/.*/', \$collectdir,
40 'defaultlang/.*/', \$defaultlang)) {
41 &print_usage();
42 die "\n";
43 }
44
45 # get and check the collection name
46 my ($collection) = @ARGV;
47 if (!defined($collection) || $collection eq "") {
48 die "No collection specified\n";
49 }
50 if ($collection eq "gs2model") {
51 die "You cant convert the model collection\n";
52 }
53
54 if (!defined $collectdir || $collectdir eq "") {
55 $collectdir = &util::filename_cat ($ENV{'GSDLHOME'}, "collect");
56 }
57
58 if (!defined $defaultlang || $defaultlang eq "") {
59 $defaultlang = 'en';
60 }
61 # add on the coll name
62 $collectdir = &util::filename_cat ($collectdir, $collection);
63
64 my $collconfigfilename = &util::filename_cat ($collectdir, "etc", "collect.cfg");
65 print STDOUT "coll config=$collconfigfilename\n";
66 my $collectcfg;
67 if (-e $collconfigfilename) {
68 $collectcfg = &colcfg::read_collect_cfg ($collconfigfilename);
69
70 } else {
71 print STDERR "collect.cfg not found!!";
72 die "\n";
73 }
74
75
76 my $buildconfigfilename = &util::filename_cat ($collectdir, "index", "build.cfg");
77 my $buildcfg;
78 if (-e $buildconfigfilename) {
79 $buildcfg = &colcfg::read_build_cfg ($buildconfigfilename);
80
81 } else {
82 print STDERR "build.cfg not found!!";
83 die "\n";
84 }
85
86
87
88 my $colloutfile = &util::filename_cat ($collectdir, "etc", "collectionConfig.xml");
89 if (-e $colloutfile) {
90 print STDOUT "collectionConfig file already exists! overwriting it!\n";
91
92 }
93
94 my $buildoutfile = &util::filename_cat ($collectdir, "index", "buildConfig.xml");
95 if (-e $buildoutfile) {
96 print STDOUT "buildConfig file already exists! overwriting it!\n";
97
98 }
99
100# my $db_file = &util::filename_cat ($collectdir, "index", "text", "$collection.ldb");
101 my $database;
102# if (-e $db_file) {
103# $database = &open_database($db_file);
104# } else {
105# print STDERR "gdbm database file $db_file not found!!";
106# die "\n";
107# }
108
109 my $buildtype;
110 if (defined $buildcfg->{'buildtype'}) {
111 $buildtype = $buildcfg->{'buildtype'};
112 } else {
113 $buildtype = 'mg';
114 }
115
116 my $indexstem = undef;
117 if (defined $buildcfg->{'indexstem'}) {
118 $indexstem = $buildcfg->{'indexstem'};
119 }
120
121 my $buildoutput = new IO::File(">$buildoutfile");
122 my $buildwriter = new XML::Writer(OUTPUT => $buildoutput, NEWLINES => 1);
123
124 $buildwriter->startTag('buildConfig', 'xmlns:gsf'=>"http://www.greenstone.org/greenstone3/schema/ConfigFormat");
125
126 my $colloutput = new IO::File(">$colloutfile");
127 my $collwriter = new XML::Writer(OUTPUT => $colloutput, NEWLINES => 1);
128
129 $collwriter->startTag('collectionConfig', 'xmlns:gsf'=>"http://www.greenstone.org/greenstone3/schema/ConfigFormat", 'xmlns:xsl'=>'http://www.w3.org/1999/XSL/Transform');
130
131 #output the collection metadata to the collectionConfig file
132 $collwriter->startTag('metadataList');
133
134 my $creator = $collectcfg->{'creator'};
135 &output_metadata($collwriter, 'creator', $creator);
136 $collwriter->endTag('metadataList');
137
138 #output the display collectionmeta to collectionConfig.xml
139
140 my $collectionmeta = $collectcfg->{'collectionmeta'};
141 if (defined $collectionmeta) {
142 my %name_map = ('collectionname', 'name',
143 'collectionextra', 'description',
144 'iconcollection', 'icon',
145 'iconcollectionsmall', 'smallicon');
146
147 $collwriter->startTag('displayItemList');
148 foreach my $entry ( keys %$collectionmeta) {
149 if (defined $name_map{$entry}) {
150 my $name= $name_map{$entry};
151 foreach my $lang (keys %{$collectionmeta->{$entry}}) {
152 my $value = $collectionmeta->{$entry}->{$lang};
153 if ($entry =~ /^icon/) {
154 $value = format_icon_value($value);
155 } else {
156 $value = tidy_up_metadata($value);
157 }
158 &output_display($collwriter, $name, $lang, $value);
159 }
160 }
161 }
162 $collwriter->endTag('displayItemList');
163 }
164
165 # output building metadata to build config file
166 my $numdocs = $buildcfg->{'numdocs'};
167 $buildwriter->startTag('metadataList');
168 &output_metadata($buildwriter, 'numDocs', $numdocs);
169 &output_metadata($buildwriter, 'buildType', $buildtype);
170 $buildwriter->endTag('metadataList');
171
172
173 #indexes
174 my $indexmap = {};
175 my $firstindex = "";
176 my $first = 1;
177 if (defined $buildcfg->{'indexmap'}) {
178 my $indexmap_t = $buildcfg->{'indexmap'};
179 foreach my $i (@$indexmap_t) {
180 my ($k, $v) = $i =~ /^(.*)\-\>(.*)$/;
181 $indexmap->{$k} = $v;
182 if ($first) {
183 $firstindex = $v;
184 $first = 0;
185 }
186 }
187 } else {
188 print STDERR "indexmap not defined";
189 }
190 my $defaultindex;
191 if (defined $collectcfg->{'defaultindex'}) {
192 $defaultindex = $collectcfg->{'defaultindex'};
193 $defaultindex = $indexmap->{$defaultindex};
194 } else {
195 # use the first one
196 $defaultindex = $firstindex;
197 }
198
199 # format stuff
200 my $format = $collectcfg->{'format'};
201
202 #output the search stuff to coll cfg
203 $collwriter->startTag('search');
204 foreach my $i (keys %$indexmap) {
205 my $shortname = $indexmap->{$i};
206 $collwriter->startTag('index', 'name'=>$shortname);
207 #find the coll meta stuff
208 my $indexdisplay = ".$i";
209 foreach my $lang (keys %{$collectionmeta->{$indexdisplay}}) {
210 my $value = $collectionmeta->{$indexdisplay}->{$lang};
211 output_display($collwriter, 'name', $lang, $value);
212 }
213 $collwriter->endTag('index');
214
215 }
216
217 # add in the format stuff
218 if (defined $format->{'SearchVList'}) {
219
220 $collwriter->startTag('format');
221 write_format($collwriter, $format->{'SearchVList'}, "document");
222 $collwriter->endTag('format');
223 }
224 elsif (defined $format->{'VList'}) {
225 $collwriter->startTag('format');
226 write_format($collwriter, $format->{'VList'}, "document");
227 $collwriter->endTag('format');
228 }
229
230 $collwriter->endTag('search');
231
232 $buildwriter->startTag('serviceRackList');
233
234 my @levels = ();
235 my $defaultlevel;
236
237 #do the retrieve service
238 # assume mgpp or mg
239 if ($buildtype eq 'mgpp') {
240 #for each level
241 if (defined $buildcfg->{'indexlevels'}) {
242 push @levels, @{$buildcfg->{'indexlevels'}};
243
244 if (defined $buildcfg->{'textlevel'}) {
245 $defaultlevel = $buildcfg->{'textlevel'};
246 } else {
247 $defaultlevel = $levels[0];
248 }
249 } else { #use levels from collect.cfg - must be an old collection
250 @levels = ('Document');
251 $defaultlevel = 'Document';
252 if (defined $collectcfg->{'levels'}) {
253 foreach my $l (@{$collectcfg->{'levels'}}) {
254 if ($l eq "Section") {
255 $defaultlevel = 'Section';
256 }
257 push @levels, $l;
258 }
259 }
260 }
261
262 $buildwriter->startTag('serviceRack', 'name'=>'GS2MGPPRetrieve');
263 $buildwriter->emptyTag('defaultLevel', 'name'=>$defaultlevel);
264
265
266 } else {
267 $buildwriter->startTag('serviceRack', 'name'=>'GS2MGRetrieve');
268 $buildwriter->emptyTag('defaultIndex', 'name'=>$defaultindex);
269
270 }
271 if (defined $indexstem) {
272 $buildwriter->emptyTag('indexStem', 'name'=>$indexstem);
273 }
274 # close off the Retrieve service
275 $buildwriter->endTag('serviceRack');
276
277 # add in the classifiers if needed
278
279 my $count = 1;
280 my $phind = 0;
281 my $started_classifiers = 0;
282 if (defined $collectcfg->{'classify'}) {
283 $collwriter->startTag('browse');
284 # add in default format if necessary
285 if (defined $format->{"VList"} || defined $format->{"HList"}) {
286 # global formats
287 $collwriter->startTag('format');
288 if (defined $format->{"VList"}) {
289 # VLIst applies to both classifier and doc nodes
290 write_format($collwriter, $format->{"VList"}, "document");
291 write_format($collwriter, $format->{"VList"}, "classifier");
292 }
293 if (defined $format->{"HList"}) {
294 # hlist is only for classifier nodes
295 write_format($collwriter, $format->{"HList"}, "horizontal");
296 }
297 $collwriter->endTag('format');
298 }
299 my $classifiers = $collectcfg->{'classify'};
300 foreach my $cl (@$classifiers) {
301 my $name = "CL$count";
302 $count++;
303 my ($classname) = @$cl[0];
304 if ($classname =~ /^phind$/i) {
305 $phind=1;
306 #should add it into coll config classifiers
307 next;
308 }
309
310 my $horizontalAtTop = &isHorizontalClassifier($database, $name);
311 if (not $started_classifiers) {
312 $buildwriter->startTag('serviceRack', 'name'=>'GS2Browse');
313 if (defined $indexstem) {
314 $buildwriter->emptyTag('indexStem', 'name'=>$indexstem);
315 }
316
317 $buildwriter->startTag('classifierList');
318 $started_classifiers = 1;
319 }
320 my $content = ''; #use buttonname first, then metadata
321 if ($classname eq "DateList") {
322 $content = "Date";
323 } else {
324 for (my $i=0; $i<scalar(@$cl); $i++) {
325 my $arg = @$cl[$i];
326 if ($arg eq "-buttonname"){
327 $content = @$cl[$i+1];
328 last;
329 } elsif ($arg eq "-metadata") {
330 $content = @$cl[$i+1];
331 }
332
333 }
334 }
335 if ($horizontalAtTop) {
336 $buildwriter->emptyTag('classifier', 'name'=>$name, 'content'=>$content, 'horizontalAtTop'=>'true');
337 } else {
338 $buildwriter->emptyTag('classifier', 'name'=>$name, 'content'=>$content);
339 }
340
341
342 $collwriter->startTag('classifier', 'name'=>$name);
343 my $vlist = $name."VList";
344 my $hlist = $name."HList";
345 my $dlist = "";
346 if ($classname eq "DateList") {
347 $dlist = "DateList";
348 }
349 # need to work out how to split into classifier and document
350 if (defined $format->{$vlist} || defined $format->{$hlist} || defined $format->{$dlist}) {
351 $collwriter->startTag('format');
352 if (defined $format->{$vlist}) {
353 write_format($collwriter, $format->{$vlist}, "document");
354 write_format($collwriter, $format->{$vlist}, "classifier");
355 }
356 if (defined $format->{$hlist}) {
357 write_format($collwriter, $format->{$hlist}, "horizontal");
358 }
359
360 if (defined $format->{$dlist}) {
361 write_format($collwriter, $format->{$dlist}, "document");
362 }
363 $collwriter->endTag('format');
364 }
365 $collwriter->endTag('classifier');
366 } #foreach classifier
367 if ($started_classifiers) {
368 # end the classifiers
369 $buildwriter->endTag('classifierList');
370 # close off the Browse service
371 $buildwriter->endTag('serviceRack');
372 }
373
374 $collwriter->endTag('browse');
375 }
376
377
378 # the phind classifier is a separate service
379 if ($phind) {
380 # if phind classifier
381 $buildwriter->emptyTag('serviceRack', 'name'=>'PhindPhraseBrowse');
382 }
383
384 # do the search service
385 if ($buildtype eq 'mgpp') {
386
387 $buildwriter->startTag('serviceRack', 'name'=>'GS2MGPPSearch');
388 $buildwriter->emptyTag('defaultLevel', 'name'=>$defaultlevel);
389 $buildwriter->startTag('levelList');
390 foreach my $level (@levels) {
391 $buildwriter->emptyTag('level', 'name'=>$level);
392 }
393 $buildwriter->endTag('levelList');
394
395 #fieldlist
396 my $fieldmap = {};
397 my $fieldlist = ();
398 if (defined $buildcfg->{'indexfields'}) {
399 push @$fieldlist, @{$buildcfg->{'indexfields'}};
400 if (defined $buildcfg->{'indexfieldmap'}) {
401 my $fieldmap_t = $buildcfg->{'indexfieldmap'};
402 foreach my $f (@$fieldmap_t) {
403 my ($k, $v) = $f =~ /^(.*)\-\>(.*)$/;
404 $fieldmap->{$k} = $v;
405 }
406 }
407 $buildwriter->startTag('fieldList');
408 foreach my $f (@$fieldlist) {
409 my $field = $fieldmap->{$f};
410 $buildwriter->emptyTag('field', 'shortname'=>$field, 'name'=>$f);
411 }
412 $buildwriter->endTag('fieldList');
413 } else {
414 print STDERR "indexfieldmap not defined";
415 }
416
417 # do the search types if there
418 if (defined $collectcfg->{'searchtype'}) {
419 $buildwriter->startTag('searchTypeList');
420 foreach my $st (@{$collectcfg->{'searchtype'}}) {
421 $buildwriter->emptyTag('searchType', 'name'=>$st);
422 }
423 $buildwriter->endTag('searchTypeList');
424 }
425 } elsif ($buildtype eq 'mg') {
426 $buildwriter->startTag('serviceRack', 'name'=>'GS2MGSearch');
427 }
428
429 if (defined $indexstem) {
430 $buildwriter->emptyTag('indexStem', 'name'=>$indexstem);
431 }
432
433 $buildwriter->emptyTag('defaultIndex', 'name'=>$defaultindex);
434 $buildwriter->startTag('indexList');
435 #for each index
436 foreach my $i (keys %$indexmap) {
437 my $index = $indexmap->{$i};
438 $buildwriter->emptyTag('index', 'name'=>$index);
439 }
440 $buildwriter->endTag('indexList');
441
442 $buildwriter->endTag('serviceRack');
443
444 $buildwriter->endTag('serviceRackList');
445 $buildwriter->endTag('buildConfig');
446
447 # we add in the default replace list just in case we have macros in the
448 # collection
449 $collwriter->emptyTag('replaceListRef', 'id'=>'gs2-standard');
450 $collwriter->endTag('collectionConfig');
451 $collwriter->end();
452 $buildwriter->end();
453 $buildoutput->close();
454 $colloutput->close();
455 &close_database($database);
456}
457
458
459sub output_metadata {
460 my ($writer, $metaname, $metavalue) = @_;
461 $writer->startTag('metadata', 'name'=>$metaname);
462 $writer->characters($metavalue);
463 $writer->endTag('metadata');
464}
465
466sub output_display {
467 my ($writer, $name, $lang, $value) = @_;
468 $lang = 'en' if $lang eq 'default';
469 if ($lang =~ /^\[/) {
470 ($lang) = $lang =~ /\[l=(.*)\]/;
471 }
472 $writer->startTag('displayItem', 'name'=>$name, 'lang'=>$lang);
473 $writer->characters($value);
474 $writer->endTag('displayItem');
475}
476sub format_icon_value {
477 my ($value) = @_;
478 if ($value =~ /^_/) {
479 my ($newvalue) = $value =~ /\/([^\/]*)$/;
480 if ($newvalue) {
481 return $newvalue;
482 }
483 }
484 return $value;
485}
486
487sub tidy_up_metadata {
488 my ($value) = @_;
489 # remove \n
490 $value =~ s/\\n//g;
491 # replace \' with '
492 $value =~ s/\\\'/\'/g;
493 # replace \" with "
494 $value =~ s/\\\"/\"/g;
495 return $value;
496}
497
498sub write_format {
499 my ($writer, $old_format, $node_type) = @_;
500 # replace \' with '
501 $old_format =~ s/\\\'/\'/g;
502 # replace \" with "
503 $old_format =~ s/\\\"/\"/g;
504 #convert [] to <gsf:...>
505 # assume no nesting {If} or {Or} for now
506 $old_format =~ s/\{If\}\{([^\}]*)\}/&format_if($1, $node_type)/eg;
507 $old_format =~ s/\{Or\}\{([^\}]*)\}/&format_or($1)/eg;
508 $old_format =~ s/\[Text\]/\<gsf:text\/\>/g;
509 $old_format =~ s/\[num\]/\<gsf:num\/\>/g;
510 $old_format =~ s/\[link\]/\<gsf:link type=\'$node_type\'\>/g;
511 $old_format =~ s/\[\/link\]/\<\/gsf:link\>/g;
512 $old_format =~ s/\[srclink\]/\<gsf:link type=\'source\'\>/g;
513 $old_format =~ s/\[\/srclink\]/\<\/gsf:link\>/g;
514 $old_format =~ s/\[icon\]/\<gsf:icon type=\'$node_type\'\/\>/g;
515 $old_format =~ s/\[srcicon\]/\<gsf:icon type=\'source\'\/\>/g;
516
517 # what to do with hightlight??
518 $old_format =~ s/\[\/?highlight\]//g;
519
520 #now do the rest of the [] which are assumed to be metadata
521 $old_format =~ s/\[([^\]]*)\]/&format_metadata($1)/eg;
522
523 # some html tidy
524 #turn <br> into <br />
525 $old_format =~ s/\<br\>/\<br \/\>/g;
526 #turn <p> into <p />
527 $old_format =~ s/\<p\>/\<p \/\>/g;
528
529 #put quotes around any atts
530 $old_format =~ s/=([a-z]+)([> ])/=\'$1\'$2/g;
531
532 if ($node_type eq "document") {
533 $writer->startTag('gsf:template', 'match'=>'documentNode');
534 $writer->charactersXML($old_format);
535 $writer->endTag('gsf:template');
536 } elsif ($node_type eq "classifier") {
537 $writer->startTag('gsf:template', 'match'=>'classifierNode');
538 $writer->charactersXML($old_format);
539 $writer->endTag('gsf:template');
540 } elsif ($node_type eq "horizontal") {
541 $writer->startTag('gsf:template', 'match'=>'classifierNode', 'mode'=>'horizontal');
542 $writer->charactersXML($old_format);
543 $writer->endTag('gsf:template');
544
545 }
546}
547
548sub format_metadata {
549 my ($metadata_string) = @_;
550
551 #print STDERR "original meta = $metadata_string\n";
552
553 # what shall we do with cgisafe??
554 my $cgisafe = $metadata_string =~ s/^cgisafe://;
555
556 my ($select) = $metadata_string =~ /^(parent|sibling)/;
557 $metadata_string =~ s/^(parent|sibling)//;
558 my ($scope, $delim);
559
560 if ($select) {
561 ($scope) = $metadata_string =~ /^\((Top|All)/;
562 $metadata_string =~ s/^\((Top|All)\)?//;
563 if ($scope) {
564 ($delim) = $metadata_string =~ /^\'([^\']*)\'\)/;
565 $metadata_string =~ s/^\'([^\']*)\'\)//;
566 }
567 }
568 $metadata_string =~ s/^://;
569 # remove ex.
570 $metadata_string =~ s/^ex\.//;
571
572 #print STDERR "select=$select, scope=$scope, delim=|$delim|, meta = $metadata_string\n";
573
574 my $new_format = "<gsf:metadata name='$metadata_string' ";
575 if (defined $select) {
576 if ($select eq "sibling") {
577 $new_format .= "multiple='true' ";
578 if (defined $delim) {
579 $new_format .= "separator='$delim' ";
580 }
581 } elsif ($select eq "parent"){
582 if (defined $scope) {
583 if ($scope eq "Top") {
584 $new_format .= "select='root' ";
585 } elsif ($scope eq "All") {
586 $new_format .= "select='ancestors' ";
587 if (defined $delim) {
588 $new_format .= "separator='$delim' ";
589 }
590 }
591 } else {
592 $new_format .= "select='parent' ";
593 }
594 }
595 }
596 $new_format .= "/>";
597 #print STDERR "$new_format\n";
598 return $new_format;
599
600}
601
602sub format_if {
603
604 my ($if_string, $node_type) = @_;
605 #print STDERR "if string = $if_string\n";
606
607 my @parts = split /,/, $if_string;
608 my $test = $parts[0];
609 my $true_option = $parts[1];
610 my $false_option;
611 if (scalar (@parts) == 3) {
612 $false_option = $parts[2];
613 }
614 $test =~ s/^\s*//;
615 $test =~ s/\s*$//;
616 my ($test_meta, $test_type, $test_value);
617 if ($test =~ /^(\[.+\])$/) {
618 $test_meta = $1;
619 $test_type = 'exists';
620 } else {
621 my ($lhs, $exp, $rhs) = $test =~ /^(.+)\s+(eq|ne|lt|gt|le|ge|sw|ew)\s+(.+)$/;
622 #print STDERR "lhs, exp, rhs = $lhs, $exp, $rhs\n";
623 if ($exp eq "eq") {
624 $test_type = "equals";
625 } elsif ($exp eq "sw") {
626 $test_type = "startsWith";
627 } elsif ($exp eq "ew") {
628 $test_type = "endsWith";
629 } elsif ($exp eq "ne") {
630 $test_type = "notEquals";
631 } elsif ($exp eq "lt") {
632 $test_type = "lessThan";
633 }elsif ($exp eq "gt") {
634 $test_type = "greaterThan";
635 }elsif ($exp eq "le") {
636 $test_type = "lessThanOrEquals";
637 }elsif ($exp eq "ge") {
638 $test_type = "greaterThanOrEquals";
639 }
640 if ($lhs =~ /^\[.+\]$/) {
641 $test_meta = $lhs;
642 $test_value = $rhs;
643 } else {
644 # assume rhs has meta
645 $test_meta = $rhs;
646 $test_value = $lhs;
647 }
648
649 #remove beginning and end quotes
650 $test_value =~ s/^[\'\"]//;
651 $test_value =~ s/[\'\"]$//;
652 }
653 my $test_atts = "test='$test_type' ";
654 if (defined $test_value) {
655 $test_atts .= "test-value='$test_value' ";
656 }
657 #print STDERR "test, true, false = $test, $true_option, $false_option\n";
658 my $new_format = "<gsf:switch>$test_meta";
659 $new_format .= "<gsf:when $test_atts>$true_option</gsf:when>";
660 if (defined $false_option) {
661 $new_format .="<gsf:otherwise>$false_option</gsf:otherwise>";
662 }
663 $new_format .= "</gsf:switch>";
664
665 #print STDERR "new format = $new_format\n";
666 return $new_format;
667}
668
669sub format_or {
670 my ($or_string) = @_;
671 my @meta_list = split (',', $or_string);
672 return "" unless scalar (@meta_list);
673 my $new_format = "<gsf:choose-metadata>";
674 foreach my $m (@meta_list) {
675 if ($m =~ /^\[(.*)\]$/) {
676 $new_format .= &format_metadata($1);
677 } else {
678 # a default value
679 $new_format .= "<gsf:default>$m</gsf:default>";
680 last;
681 }
682 }
683 $new_format .= "</gsf:choose-metadata>";
684 return $new_format;
685}
686
687sub open_database {
688 my ($db_file) = @_;
689
690 my $database = ();
691# tie (%$database, 'GDBM_File', $db_file, GDBM_READER, 0400) ||
692# die "Couldn't open database $db_file\n";
693
694 return $database;
695}
696
697sub close_database {
698 my ($database) = @_;
699 untie %$database;
700}
701sub isHorizontalClassifier {
702 my ($database, $name) = @_;
703
704 return 0; # can't get this to work for windows
705 my $record = $database->{$name};
706 my ($childtype) = $record =~ /<childtype>(\w*)/;
707 if ($childtype eq "HList") {
708 return 1;
709 }
710 return 0;
711}
712#$writer->startTag('');
713#$writer->endTag('');
714#$writer->characters();
715#$writer->emptyTag('');
716
7171;
Note: See TracBrowser for help on using the repository browser.