source: main/trunk/greenstone2/perllib/util.pm@ 21762

Last change on this file since 21762 was 21762, checked in by kjdon, 14 years ago

creating a cd currently copies all svn directories. added a cp_r_nosvn method to util, and use that when copying stuff to cd
  • Property svn:keywords set to Author Date Id Revision
File size: 34.0 KB
Line 
1###########################################################################
2#
3# util.pm -- various useful utilities
4# A component of the Greenstone digital library software
5# from the New Zealand Digital Library Project at the
6# University of Waikato, New Zealand.
7#
8# Copyright (C) 1999 New Zealand Digital Library Project
9#
10# This program is free software; you can redistribute it and/or modify
11# it under the terms of the GNU General Public License as published by
12# the Free Software Foundation; either version 2 of the License, or
13# (at your option) any later version.
14#
15# This program is distributed in the hope that it will be useful,
16# but WITHOUT ANY WARRANTY; without even the implied warranty of
17# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18# GNU General Public License for more details.
19#
20# You should have received a copy of the GNU General Public License
21# along with this program; if not, write to the Free Software
22# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
23#
24###########################################################################
25
26package util;
27
28use File::Copy;
29use File::Basename;
30
31use strict;
32
33
34# removes files (but not directories)
35sub rm {
36 my (@files) = @_;
37
38 my @filefiles = ();
39
40 # make sure the files we want to delete exist
41 # and are regular files
42 foreach my $file (@files) {
43 if (!-e $file) {
44 print STDERR "util::rm $file does not exist\n";
45 } elsif ((!-f $file) && (!-l $file)) {
46 print STDERR "util::rm $file is not a regular (or symbolic) file\n";
47 } else {
48 push (@filefiles, $file);
49 }
50 }
51
52 # remove the files
53 my $numremoved = unlink @filefiles;
54
55 # check to make sure all of them were removed
56 if ($numremoved != scalar(@filefiles)) {
57 print STDERR "util::rm Not all files were removed\n";
58 }
59}
60
61
62
63# recursive removal
64sub filtered_rm_r {
65 my ($files,$file_accept_re,$file_reject_re) = @_;
66
67 my @files_array = (ref $files eq "ARRAY") ? @$files : ($files);
68
69 # recursively remove the files
70 foreach my $file (@files_array) {
71 $file =~ s/[\/\\]+$//; # remove trailing slashes
72
73 if (!-e $file) {
74 print STDERR "util::filtered_rm_r $file does not exist\n";
75
76 } elsif ((-d $file) && (!-l $file)) { # don't recurse down symbolic link
77 # get the contents of this directory
78 if (!opendir (INDIR, $file)) {
79 print STDERR "util::filtered_rm_r could not open directory $file\n";
80 } else {
81 my @filedir = grep (!/^\.\.?$/, readdir (INDIR));
82 closedir (INDIR);
83
84 # remove all the files in this directory
85 map {$_="$file/$_";} @filedir;
86 &filtered_rm_r (\@filedir,$file_accept_re,$file_reject_re);
87
88 if (!defined $file_accept_re && !defined $file_reject_re) {
89 # remove this directory
90 if (!rmdir $file) {
91 print STDERR "util::filtered_rm_r couldn't remove directory $file\n";
92 }
93 }
94 }
95 } else {
96 next if (defined $file_reject_re && ($file =~ m/$file_reject_re/));
97
98 if ((!defined $file_accept_re) || ($file =~ m/$file_accept_re/)) {
99 # remove this file
100 &rm ($file);
101 }
102 }
103 }
104}
105
106
107# recursive removal
108sub rm_r {
109 my (@files) = @_;
110
111 # use the more general (but reterospectively written function
112 # filtered_rm_r function()
113
114 filtered_rm_r(\@files,undef,undef); # no accept or reject expressions
115}
116
117
118
119
120# moves a file or a group of files
121sub mv {
122 my $dest = pop (@_);
123 my (@srcfiles) = @_;
124
125 # remove trailing slashes from source and destination files
126 $dest =~ s/[\\\/]+$//;
127 map {$_ =~ s/[\\\/]+$//;} @srcfiles;
128
129 # a few sanity checks
130 if (scalar (@srcfiles) == 0) {
131 print STDERR "util::mv no destination directory given\n";
132 return;
133 } elsif ((scalar (@srcfiles) > 1) && (!-d $dest)) {
134 print STDERR "util::mv if multiple source files are given the ".
135 "destination must be a directory\n";
136 return;
137 }
138
139 # move the files
140 foreach my $file (@srcfiles) {
141 my $tempdest = $dest;
142 if (-d $tempdest) {
143 my ($filename) = $file =~ /([^\\\/]+)$/;
144 $tempdest .= "/$filename";
145 }
146 if (!-e $file) {
147 print STDERR "util::mv $file does not exist\n";
148 } else {
149 rename ($file, $tempdest);
150 }
151 }
152}
153
154
155# copies a file or a group of files
156sub cp {
157 my $dest = pop (@_);
158 my (@srcfiles) = @_;
159
160 # remove trailing slashes from source and destination files
161 $dest =~ s/[\\\/]+$//;
162 map {$_ =~ s/[\\\/]+$//;} @srcfiles;
163
164 # a few sanity checks
165 if (scalar (@srcfiles) == 0) {
166 print STDERR "util::cp no destination directory given\n";
167 return;
168 } elsif ((scalar (@srcfiles) > 1) && (!-d $dest)) {
169 print STDERR "util::cp if multiple source files are given the ".
170 "destination must be a directory\n";
171 return;
172 }
173
174 # copy the files
175 foreach my $file (@srcfiles) {
176 my $tempdest = $dest;
177 if (-d $tempdest) {
178 my ($filename) = $file =~ /([^\\\/]+)$/;
179 $tempdest .= "/$filename";
180 }
181 if (!-e $file) {
182 print STDERR "util::cp $file does not exist\n";
183 } elsif (!-f $file) {
184 print STDERR "util::cp $file is not a plain file\n";
185 } else {
186 &File::Copy::copy ($file, $tempdest);
187 }
188 }
189}
190
191
192
193# recursively copies a file or group of files
194# syntax: cp_r (sourcefiles, destination directory)
195# destination must be a directory - to copy one file to
196# another use cp instead
197sub cp_r {
198 my $dest = pop (@_);
199 my (@srcfiles) = @_;
200
201 # a few sanity checks
202 if (scalar (@srcfiles) == 0) {
203 print STDERR "util::cp_r no destination directory given\n";
204 return;
205 } elsif (-f $dest) {
206 print STDERR "util::cp_r destination must be a directory\n";
207 return;
208 }
209
210 # create destination directory if it doesn't exist already
211 if (! -d $dest) {
212 my $store_umask = umask(0002);
213 mkdir ($dest, 0777);
214 umask($store_umask);
215 }
216
217 # copy the files
218 foreach my $file (@srcfiles) {
219
220 if (!-e $file) {
221 print STDERR "util::cp_r $file does not exist\n";
222
223 } elsif (-d $file) {
224 # make the new directory
225 my ($filename) = $file =~ /([^\\\/]*)$/;
226 $dest = &util::filename_cat ($dest, $filename);
227 my $store_umask = umask(0002);
228 mkdir ($dest, 0777);
229 umask($store_umask);
230
231 # get the contents of this directory
232 if (!opendir (INDIR, $file)) {
233 print STDERR "util::cp_r could not open directory $file\n";
234 } else {
235 my @filedir = readdir (INDIR);
236 closedir (INDIR);
237 foreach my $f (@filedir) {
238 next if $f =~ /^\.\.?$/;
239 # copy all the files in this directory
240 my $ff = &util::filename_cat ($file, $f);
241 &cp_r ($ff, $dest);
242 }
243 }
244
245 } else {
246 &cp($file, $dest);
247 }
248 }
249}
250# recursively copies a file or group of files
251# syntax: cp_r (sourcefiles, destination directory)
252# destination must be a directory - to copy one file to
253# another use cp instead
254sub cp_r_nosvn {
255 my $dest = pop (@_);
256 my (@srcfiles) = @_;
257
258 # a few sanity checks
259 if (scalar (@srcfiles) == 0) {
260 print STDERR "util::cp_r no destination directory given\n";
261 return;
262 } elsif (-f $dest) {
263 print STDERR "util::cp_r destination must be a directory\n";
264 return;
265 }
266
267 # create destination directory if it doesn't exist already
268 if (! -d $dest) {
269 my $store_umask = umask(0002);
270 mkdir ($dest, 0777);
271 umask($store_umask);
272 }
273
274 # copy the files
275 foreach my $file (@srcfiles) {
276
277 if (!-e $file) {
278 print STDERR "util::cp_r $file does not exist\n";
279
280 } elsif (-d $file) {
281 # make the new directory
282 my ($filename) = $file =~ /([^\\\/]*)$/;
283 $dest = &util::filename_cat ($dest, $filename);
284 my $store_umask = umask(0002);
285 mkdir ($dest, 0777);
286 umask($store_umask);
287
288 # get the contents of this directory
289 if (!opendir (INDIR, $file)) {
290 print STDERR "util::cp_r could not open directory $file\n";
291 } else {
292 my @filedir = readdir (INDIR);
293 closedir (INDIR);
294 foreach my $f (@filedir) {
295 next if $f =~ /^\.\.?$/;
296 next if $f =~ /^\.svn$/;
297 # copy all the files in this directory
298 my $ff = &util::filename_cat ($file, $f);
299 &cp_r ($ff, $dest);
300 }
301 }
302
303 } else {
304 &cp($file, $dest);
305 }
306 }
307}
308
309# copies a directory and its contents, excluding subdirectories, into a new directory
310sub cp_r_toplevel {
311 my $dest = pop (@_);
312 my (@srcfiles) = @_;
313
314 # a few sanity checks
315 if (scalar (@srcfiles) == 0) {
316 print STDERR "util::cp_r no destination directory given\n";
317 return;
318 } elsif (-f $dest) {
319 print STDERR "util::cp_r destination must be a directory\n";
320 return;
321 }
322
323 # create destination directory if it doesn't exist already
324 if (! -d $dest) {
325 my $store_umask = umask(0002);
326 mkdir ($dest, 0777);
327 umask($store_umask);
328 }
329
330 # copy the files
331 foreach my $file (@srcfiles) {
332
333 if (!-e $file) {
334 print STDERR "util::cp_r $file does not exist\n";
335
336 } elsif (-d $file) {
337 # make the new directory
338 my ($filename) = $file =~ /([^\\\/]*)$/;
339 $dest = &util::filename_cat ($dest, $filename);
340 my $store_umask = umask(0002);
341 mkdir ($dest, 0777);
342 umask($store_umask);
343
344 # get the contents of this directory
345 if (!opendir (INDIR, $file)) {
346 print STDERR "util::cp_r could not open directory $file\n";
347 } else {
348 my @filedir = readdir (INDIR);
349 closedir (INDIR);
350 foreach my $f (@filedir) {
351 next if $f =~ /^\.\.?$/;
352
353 # copy all the files in this directory, but not directories
354 my $ff = &util::filename_cat ($file, $f);
355 if (-f $ff) {
356 &cp($ff, $dest);
357 #&cp_r ($ff, $dest);
358 }
359 }
360 }
361
362 } else {
363 &cp($file, $dest);
364 }
365 }
366}
367
368sub mk_dir {
369 my ($dir) = @_;
370
371 my $store_umask = umask(0002);
372 my $mkdir_ok = mkdir ($dir, 0777);
373 umask($store_umask);
374
375 if (!$mkdir_ok)
376 {
377 print STDERR "util::mk_dir could not create directory $dir\n";
378 return;
379 }
380}
381
382# in case anyone cares - I did some testing (using perls Benchmark module)
383# on this subroutine against File::Path::mkpath (). mk_all_dir() is apparently
384# slightly faster (surprisingly) - Stefan.
385sub mk_all_dir {
386 my ($dir) = @_;
387
388 # use / for the directory separator, remove duplicate and
389 # trailing slashes
390 $dir=~s/[\\\/]+/\//g;
391 $dir=~s/[\\\/]+$//;
392
393 # make sure the cache directory exists
394 my $dirsofar = "";
395 my $first = 1;
396 foreach my $dirname (split ("/", $dir)) {
397 $dirsofar .= "/" unless $first;
398 $first = 0;
399
400 $dirsofar .= $dirname;
401
402 next if $dirname =~ /^(|[a-z]:)$/i;
403 if (!-e $dirsofar)
404 {
405 my $store_umask = umask(0002);
406 my $mkdir_ok = mkdir ($dirsofar, 0777);
407 umask($store_umask);
408 if (!$mkdir_ok)
409 {
410 print STDERR "util::mk_all_dir could not create directory $dirsofar\n";
411 return;
412 }
413 }
414 }
415}
416
417# make hard link to file if supported by OS, otherwise copy the file
418sub hard_link {
419 my ($src, $dest, $verbosity) = @_;
420
421 # remove trailing slashes from source and destination files
422 $src =~ s/[\\\/]+$//;
423 $dest =~ s/[\\\/]+$//;
424
425 # a few sanity checks
426 if (-e $dest) {
427 # destination file already exists
428 return;
429 }
430 elsif (!-e $src) {
431 print STDERR "util::hard_link source file $src does not exist\n";
432 return 1;
433 }
434 elsif (-d $src) {
435 print STDERR "util::hard_link source $src is a directory\n";
436 return 1;
437 }
438
439 my $dest_dir = &File::Basename::dirname($dest);
440 mk_all_dir($dest_dir) if (!-e $dest_dir);
441
442 # link not supported on windows 9x
443 if (($ENV{'GSDLOS'} =~ /^windows$/i) && (Win32::FsType() !~ /^ntfs$/i)) {
444 &File::Copy::copy ($src, $dest);
445
446 } elsif (!link($src, $dest)) {
447 if ((!defined $verbosity) || ($verbosity>2)) {
448 print STDERR "util::hard_link: unable to create hard link. ";
449 print STDERR " Copying file: $src -> $dest\n";
450 }
451 &File::Copy::copy ($src, $dest);
452 }
453 return 0;
454}
455
456# make soft link to file if supported by OS, otherwise copy file
457sub soft_link {
458 my ($src, $dest, $ensure_paths_absolute) = @_;
459
460 # remove trailing slashes from source and destination files
461 $src =~ s/[\\\/]+$//;
462 $dest =~ s/[\\\/]+$//;
463
464 # Ensure file paths are absolute IF requested to do so
465 # Soft_linking didn't work for relative paths
466 if(defined $ensure_paths_absolute && $ensure_paths_absolute) {
467 # We need to ensure that the src file is the absolute path
468 # See http://perldoc.perl.org/File/Spec.html
469 if(!File::Spec->file_name_is_absolute( $src )) { # it's relative
470 $src = File::Spec->rel2abs($src); # make absolute
471 }
472 # Might as well ensure that the destination file's absolute path is used
473 if(!File::Spec->file_name_is_absolute( $dest )) {
474 $dest = File::Spec->rel2abs($dest); # make absolute
475 }
476 }
477
478 # a few sanity checks
479 if (!-e $src) {
480 print STDERR "util::soft_link source file $src does not exist\n";
481 return 0;
482 }
483
484 my $dest_dir = &File::Basename::dirname($dest);
485 mk_all_dir($dest_dir) if (!-e $dest_dir);
486
487 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
488 # symlink not supported on windows
489 &File::Copy::copy ($src, $dest);
490
491 } elsif (!eval {symlink($src, $dest)}) {
492 print STDERR "util::soft_link: unable to create soft link.\n";
493 return 0;
494 }
495
496 return 1;
497}
498
499
500
501
502# updates a copy of a directory in some other part of the filesystem
503# verbosity settings are: 0=low, 1=normal, 2=high
504# both $fromdir and $todir should be absolute paths
505sub cachedir {
506 my ($fromdir, $todir, $verbosity) = @_;
507 $verbosity = 1 unless defined $verbosity;
508
509 # use / for the directory separator, remove duplicate and
510 # trailing slashes
511 $fromdir=~s/[\\\/]+/\//g;
512 $fromdir=~s/[\\\/]+$//;
513 $todir=~s/[\\\/]+/\//g;
514 $todir=~s/[\\\/]+$//;
515
516 &mk_all_dir ($todir);
517
518 # get the directories in ascending order
519 if (!opendir (FROMDIR, $fromdir)) {
520 print STDERR "util::cachedir could not read directory $fromdir\n";
521 return;
522 }
523 my @fromdir = grep (!/^\.\.?$/, sort(readdir (FROMDIR)));
524 closedir (FROMDIR);
525
526 if (!opendir (TODIR, $todir)) {
527 print STDERR "util::cacedir could not read directory $todir\n";
528 return;
529 }
530 my @todir = grep (!/^\.\.?$/, sort(readdir (TODIR)));
531 closedir (TODIR);
532
533 my $fromi = 0;
534 my $toi = 0;
535
536 while ($fromi < scalar(@fromdir) || $toi < scalar(@todir)) {
537# print "fromi: $fromi toi: $toi\n";
538
539 # see if we should delete a file/directory
540 # this should happen if the file/directory
541 # is not in the from list or if its a different
542 # size, or has an older timestamp
543 if ($toi < scalar(@todir)) {
544 if (($fromi >= scalar(@fromdir)) ||
545 ($todir[$toi] lt $fromdir[$fromi] ||
546 ($todir[$toi] eq $fromdir[$fromi] &&
547 &differentfiles("$fromdir/$fromdir[$fromi]","$todir/$todir[$toi]",
548 $verbosity)))) {
549
550 # the files are different
551 &rm_r("$todir/$todir[$toi]");
552 splice(@todir, $toi, 1); # $toi stays the same
553
554 } elsif ($todir[$toi] eq $fromdir[$fromi]) {
555 # the files are the same
556 # if it is a directory, check its contents
557 if (-d "$todir/$todir[$toi]") {
558 &cachedir ("$fromdir/$fromdir[$fromi]",
559 "$todir/$todir[$toi]", $verbosity);
560 }
561
562 $toi++;
563 $fromi++;
564 next;
565 }
566 }
567
568 # see if we should insert a file/directory
569 # we should insert a file/directory if there
570 # is no tofiles left or if the tofile does not exist
571 if ($fromi < scalar(@fromdir) && ($toi >= scalar(@todir) ||
572 $todir[$toi] gt $fromdir[$fromi])) {
573 &cp_r ("$fromdir/$fromdir[$fromi]", "$todir/$fromdir[$fromi]");
574 splice (@todir, $toi, 0, $fromdir[$fromi]);
575
576 $toi++;
577 $fromi++;
578 }
579 }
580}
581
582# this function returns -1 if either file is not found
583# assumes that $file1 and $file2 are absolute file names or
584# in the current directory
585# $file2 is allowed to be newer than $file1
586sub differentfiles {
587 my ($file1, $file2, $verbosity) = @_;
588 $verbosity = 1 unless defined $verbosity;
589
590 $file1 =~ s/\/+$//;
591 $file2 =~ s/\/+$//;
592
593 my ($file1name) = $file1 =~ /\/([^\/]*)$/;
594 my ($file2name) = $file2 =~ /\/([^\/]*)$/;
595
596 return -1 unless (-e $file1 && -e $file2);
597 if ($file1name ne $file2name) {
598 print STDERR "filenames are not the same\n" if ($verbosity >= 2);
599 return 1;
600 }
601
602 my @file1stat = stat ($file1);
603 my @file2stat = stat ($file2);
604
605 if (-d $file1) {
606 if (! -d $file2) {
607 print STDERR "one file is a directory\n" if ($verbosity >= 2);
608 return 1;
609 }
610 return 0;
611 }
612
613 # both must be regular files
614 unless (-f $file1 && -f $file2) {
615 print STDERR "one file is not a regular file\n" if ($verbosity >= 2);
616 return 1;
617 }
618
619 # the size of the files must be the same
620 if ($file1stat[7] != $file2stat[7]) {
621 print STDERR "different sized files\n" if ($verbosity >= 2);
622 return 1;
623 }
624
625 # the second file cannot be older than the first
626 if ($file1stat[9] > $file2stat[9]) {
627 print STDERR "file is older\n" if ($verbosity >= 2);
628 return 1;
629 }
630
631 return 0;
632}
633
634
635sub get_tmp_filename
636{
637 my $file_ext = shift(@_) || undef;
638
639 my $opt_dot_file_ext = (defined $file_ext) ? ".$file_ext" : "";
640
641 my $tmpdir = filename_cat($ENV{'GSDLHOME'}, "tmp");
642 &mk_all_dir ($tmpdir) unless -e $tmpdir;
643
644 my $count = 1000;
645 my $rand = int(rand $count);
646 my $full_tmp_filename = &filename_cat($tmpdir, "F$rand$opt_dot_file_ext");
647
648 while (-e $full_tmp_filename) {
649 $rand = int(rand $count);
650 $full_tmp_filename = &filename_cat($tmpdir, "F$rand$opt_dot_file_ext");
651 $count++;
652 }
653
654 return $full_tmp_filename;
655}
656
657sub get_toplevel_tmp_dir
658{
659 return filename_cat($ENV{'GSDLHOME'}, "tmp");
660}
661
662
663sub filename_to_regex {
664 my $filename = shift (@_);
665
666 # need to put single backslash back to double so that regex works
667 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
668 $filename =~ s/\\/\\\\/g;
669 }
670 return $filename;
671}
672
673sub filename_cat {
674 my $first_file = shift(@_);
675 my (@filenames) = @_;
676
677# Useful for debugging
678# -- might make sense to call caller(0) rather than (1)??
679# my ($cpackage,$cfilename,$cline,$csubr,$chas_args,$cwantarray) = caller(1);
680# print STDERR "Calling method; $cfilename:$cline $cpackage->$csubr\n";
681
682 # If first_file is not null or empty, then add it back into the list
683 if (defined $first_file && $first_file =~ /\S/) {
684 unshift(@filenames, $first_file);
685 }
686
687 my $filename = join("/", @filenames);
688
689 # remove duplicate slashes and remove the last slash
690 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
691 $filename =~ s/[\\\/]+/\\/g;
692 } else {
693 $filename =~ s/[\/]+/\//g;
694 # DB: want a filename abc\de.html to remain like this
695 }
696 $filename =~ s/[\\\/]$//;
697
698 return $filename;
699}
700
701
702sub pathname_cat {
703 my $first_path = shift(@_);
704 my (@pathnames) = @_;
705
706 # If first_path is not null or empty, then add it back into the list
707 if (defined $first_path && $first_path =~ /\S/) {
708 unshift(@pathnames, $first_path);
709 }
710
711 my $join_char;
712 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
713 $join_char = ";";
714 } else {
715 $join_char = ":";
716 }
717
718 my $pathname = join($join_char, @pathnames);
719
720 # remove duplicate slashes
721 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
722 $pathname =~ s/[\\\/]+/\\/g;
723 } else {
724 $pathname =~ s/[\/]+/\//g;
725 # DB: want a pathname abc\de.html to remain like this
726 }
727
728 return $pathname;
729}
730
731
732sub tidy_up_oid {
733 my ($OID) = @_;
734 if ($OID =~ /\./) {
735 print STDERR "Warning, identifier $OID contains periods (.), removing them\n";
736 $OID =~ s/\.//g; #remove any periods
737 }
738 if ($OID =~ /^\s.*\s$/) {
739 print STDERR "Warning, identifier $OID starts or ends with whitespace. Removing it\n";
740 # remove starting and trailing whitespace
741 $OID =~ s/^\s+//;
742 $OID =~ s/\s+$//;
743 }
744 if ($OID =~ /^[\d]*$/) {
745 print STDERR "Warning, identifier $OID contains only digits. Prepending 'D'.\n";
746 $OID = "D" . $OID;
747 }
748
749 return $OID;
750}
751sub envvar_prepend {
752 my ($var,$val) = @_;
753
754 # do not prepend any value/path that's already in the environment variable
755 if ($ENV{'GSDLOS'} =~ /^windows$/i)
756 {
757 my $escaped_val = $val;
758 $escaped_val =~ s/\\/\\\\/g; # escape any Windows backslashes for upcoming regex
759 if($ENV{$var} !~ m/$escaped_val/) {
760 $ENV{$var} = "$val;".$ENV{$var};
761 }
762 }
763 else {
764 if($ENV{$var} !~ m/$val/) {
765 $ENV{$var} = "$val:".$ENV{$var};
766 }
767 }
768}
769
770sub envvar_append {
771 my ($var,$val) = @_;
772
773 # do not append any value/path that's already in the environment variable
774 if ($ENV{'GSDLOS'} =~ /^windows$/i)
775 {
776 my $escaped_val = $val;
777 $escaped_val =~ s/\\/\\\\/g; # escape any Windows backslashes for upcoming regex
778 if($ENV{$var} !~ m/$escaped_val/) {
779 $ENV{$var} .= ";$val";
780 }
781 }
782 else {
783 if($ENV{$var} !~ m/$val/) {
784 $ENV{$var} .= ":$val";
785 }
786 }
787}
788
789
790# splits a filename into a prefix and a tail extension using the tail_re, or
791# if that fails, splits on the file_extension . (dot)
792sub get_prefix_and_tail_by_regex {
793
794 my ($filename,$tail_re) = @_;
795
796 my ($file_prefix,$file_ext) = ($filename =~ m/^(.*?)($tail_re)$/);
797 if ((!defined $file_prefix) || (!defined $file_ext)) {
798 ($file_prefix,$file_ext) = ($filename =~ m/^(.*)(\..*?)$/);
799 }
800
801 return ($file_prefix,$file_ext);
802}
803
804# get full path and file only path from a base_dir (which may be empty) and
805# file (which may contain directories)
806sub get_full_filenames {
807 my ($base_dir, $file) = @_;
808
809 my $filename_full_path = $file;
810 # add on directory if present
811 $filename_full_path = &util::filename_cat ($base_dir, $file) if $base_dir =~ /\S/;
812
813 my $filename_no_path = $file;
814
815 # remove directory if present
816 $filename_no_path =~ s/^.*[\/\\]//;
817 return ($filename_full_path, $filename_no_path);
818}
819
820# returns the path of a file without the filename -- ie. the directory the file is in
821sub filename_head {
822 my $filename = shift(@_);
823
824 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
825 $filename =~ s/[^\\\\]*$//;
826 }
827 else {
828 $filename =~ s/[^\\\/]*$//;
829 }
830
831 return $filename;
832}
833
834
835# returns 1 if filename1 and filename2 point to the same
836# file or directory
837sub filenames_equal {
838 my ($filename1, $filename2) = @_;
839
840 # use filename_cat to clean up trailing slashes and
841 # multiple slashes
842 $filename1 = filename_cat ($filename1);
843 $filename2 = filename_cat ($filename2);
844
845 # filenames not case sensitive on windows
846 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
847 $filename1 =~ tr/[A-Z]/[a-z]/;
848 $filename2 =~ tr/[A-Z]/[a-z]/;
849 }
850 return 1 if $filename1 eq $filename2;
851 return 0;
852}
853
854sub filename_within_collection
855{
856 my ($filename) = @_;
857
858 my $collect_dir = $ENV{'GSDLCOLLECTDIR'};
859
860 if (defined $collect_dir) {
861 my $dirsep = &util::get_dirsep();
862 if ($collect_dir !~ m/$dirsep$/) {
863 $collect_dir .= $dirsep;
864 }
865
866 $collect_dir =~ s/\\/\\\\/g; # escape DOS style file separator
867
868 # if from within GSDLCOLLECTDIR, then remove directory prefix
869 # so source_filename is realative to it. This is done to aid
870 # portability, i.e. the collection can be moved to somewhere
871 # else on the file system and the archives directory will still
872 # work. This is needed, for example in the applet version of
873 # GLI where GSDLHOME/collect on the server will be different to
874 # the collect directory of the remove user. Of course,
875 # GSDLCOLLECTDIR subsequently needs to be put back on to turn
876 # it back into a full pathname.
877
878 if ($filename =~ /^$collect_dir(.*)$/) {
879 $filename = $1;
880 }
881 }
882
883 return $filename;
884}
885
886sub filename_is_absolute
887{
888 my ($filename) = @_;
889
890 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
891 return ($filename =~ m/^(\w:)?\\/);
892 }
893 else {
894 return ($filename =~ m/^\//);
895 }
896}
897
898
899## @method make_absolute()
900#
901# Ensure the given file path is absolute in respect to the given base path.
902#
903# @param $base_dir A string denoting the base path the given dir must be
904# absolute to.
905# @param $dir The directory to be made absolute as a string. Note that the
906# dir may already be absolute, in which case it will remain
907# unchanged.
908# @return The now absolute form of the directory as a string.
909#
910# @author John Thompson, DL Consulting Ltd.
911# @copy 2006 DL Consulting Ltd.
912#
913#used in buildcol.pl, doesn't work for all cases --kjdon
914sub make_absolute {
915
916 my ($base_dir, $dir) = @_;
917### print STDERR "dir = $dir\n";
918 $dir =~ s/[\\\/]+/\//g;
919 $dir = $base_dir . "/$dir" unless ($dir =~ m|^(\w:)?/|);
920 $dir =~ s|^/tmp_mnt||;
921 1 while($dir =~ s|/[^/]*/\.\./|/|g);
922 $dir =~ s|/[.][.]?/|/|g;
923 $dir =~ tr|/|/|s;
924### print STDERR "dir = $dir\n";
925
926 return $dir;
927}
928## make_absolute() ##
929
930sub get_dirsep {
931
932 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
933 return "\\";
934 } else {
935 return "\/";
936 }
937}
938
939sub get_os_dirsep {
940
941 if ($ENV{'GSDLOS'} =~ /^windows$/i) {
942 return "\\\\";
943 } else {
944 return "\\\/";
945 }
946}
947
948sub get_re_dirsep {
949
950 return "\\\\|\\\/";
951}
952
953
954sub get_dirsep_tail {
955 my ($filename) = @_;
956
957 # returns last part of directory or filename
958 # On unix e.g. a/b.d => b.d
959 # a/b/c => c
960
961 my $dirsep = get_re_dirsep();
962 my @dirs = split (/$dirsep/, $filename);
963 my $tail = pop @dirs;
964
965 # - caused problems under windows
966 #my ($tail) = ($filename =~ m/^(?:.*?$dirsep)?(.*?)$/);
967
968 return $tail;
969}
970
971
972# if this is running on windows we want binaries to end in
973# .exe, otherwise they don't have to end in any extension
974sub get_os_exe {
975 return ".exe" if $ENV{'GSDLOS'} =~ /^windows$/i;
976 return "";
977}
978
979
980# test to see whether this is a big or little endian machine
981sub is_little_endian
982{
983 # To determine the name of the operating system, the variable $^O is a cheap alternative to pulling it out of the Config module;
984 # If it is a Macintosh machine (i.e. the Darwin operating system), regardless if it's running on the IBM power-pc cpu or the x86 Intel-based chip with a power-pc emulator running on top of it, it's big-endian
985 # Otherwise, it's little endian
986
987 #return 0 if $^O =~ /^darwin$/i;
988 #return 0 if $ENV{'GSDLOS'} =~ /^darwin$/i;
989
990 # Going back to stating exactly whether the machine is little endian
991 # or big endian, without any special case for Macs. Since for rata it comes
992 # back with little endian and for shuttle with bigendian.
993 return (ord(substr(pack("s",1), 0, 1)) == 1);
994}
995
996
997# will return the collection name if successful, "" otherwise
998sub use_collection {
999 my ($collection, $collectdir) = @_;
1000
1001 if (!defined $collectdir || $collectdir eq "") {
1002 $collectdir = &filename_cat ($ENV{'GSDLHOME'}, "collect");
1003 }
1004
1005 # get and check the collection
1006 if (!defined($collection) || $collection eq "") {
1007 if (defined $ENV{'GSDLCOLLECTION'}) {
1008 $collection = $ENV{'GSDLCOLLECTION'};
1009 } else {
1010 print STDOUT "No collection specified\n";
1011 return "";
1012 }
1013 }
1014
1015 if ($collection eq "modelcol") {
1016 print STDOUT "You can't use modelcol.\n";
1017 return "";
1018 }
1019
1020 # make sure the environment variables GSDLCOLLECTION and GSDLCOLLECTDIR
1021 # are defined
1022 $ENV{'GSDLCOLLECTION'} = $collection;
1023 $ENV{'GSDLCOLLECTDIR'} = &filename_cat ($collectdir, $collection);
1024
1025 # make sure this collection exists
1026 if (!-e $ENV{'GSDLCOLLECTDIR'}) {
1027 print STDOUT "Invalid collection ($collection).\n";
1028 return "";
1029 }
1030
1031 # everything is ready to go
1032 return $collection;
1033}
1034
1035sub get_current_collection_name {
1036 return $ENV{'GSDLCOLLECTION'};
1037}
1038
1039
1040# will return the collection name if successful, "" otherwise.
1041# Like use_collection (above) but for greenstone 3 (taking account of site level)
1042
1043sub use_site_collection {
1044 my ($site, $collection, $collectdir) = @_;
1045
1046 if (!defined $collectdir || $collectdir eq "") {
1047 die "GSDL3HOME not set.\n" unless defined $ENV{'GSDL3HOME'};
1048 $collectdir = &filename_cat ($ENV{'GSDL3HOME'}, "sites", $site, "collect");
1049 }
1050
1051 # collectdir explicitly set by this point (using $site variable if required).
1052 # Can call "old" gsdl2 use_collection now.
1053
1054 return use_collection($collection,$collectdir);
1055}
1056
1057
1058
1059sub locate_config_file
1060{
1061 my ($file) = @_;
1062
1063 my $locations = locate_config_files($file);
1064
1065 return shift @$locations; # returns undef if 'locations' is empty
1066}
1067
1068
1069sub locate_config_files
1070{
1071 my ($file) = @_;
1072
1073 my @locations = ();
1074
1075 if (-e $file) {
1076 # Clearly specified (most likely full filename)
1077 # No need to hunt in 'etc' directories, return value unchanged
1078 push(@locations,$file);
1079 }
1080 else {
1081 # Check for collection specific one before looking in global GSDL 'etc'
1082 if (defined $ENV{'GSDLCOLLECTDIR'} && $ENV{'GSDLCOLLECTDIR'} ne "") {
1083 my $test_collect_etc_filename
1084 = &util::filename_cat($ENV{'GSDLCOLLECTDIR'},"etc", $file);
1085
1086 if (-e $test_collect_etc_filename) {
1087 push(@locations,$test_collect_etc_filename);
1088 }
1089 }
1090 my $test_main_etc_filename
1091 = &util::filename_cat($ENV{'GSDLHOME'},"etc", $file);
1092 if (-e $test_main_etc_filename) {
1093 push(@locations,$test_main_etc_filename);
1094 }
1095 }
1096
1097 return \@locations;
1098}
1099
1100
1101sub hyperlink_text
1102{
1103 my ($text) = @_;
1104
1105 $text =~ s/(http:\/\/[^\s]+)/<a href=\"$1\">$1<\/a>/mg;
1106 $text =~ s/(^|\s+)(www\.(\w|\.)+)/<a href=\"http:\/\/$2\">$2<\/a>/mg;
1107
1108 return $text;
1109}
1110
1111
1112# A method to check if a directory is empty (note that an empty directory still has non-zero size!!!)
1113# Code is from http://episteme.arstechnica.com/eve/forums/a/tpc/f/6330927813/m/436007700831
1114sub is_dir_empty
1115{
1116 my ($path) = @_;
1117 opendir DIR, $path;
1118 while(my $entry = readdir DIR) {
1119 next if($entry =~ /^\.\.?$/);
1120 closedir DIR;
1121 return 0;
1122 }
1123 closedir DIR;
1124 return 1;
1125}
1126
1127# Returns the given filename converted using either URL encoding or base64
1128# encoding, as specified by $rename_method. If the given filename has no suffix
1129# (if it is just the tailname), then $no_suffix should be some defined value.
1130# rename_method can be url, none, base64
1131sub rename_file {
1132 my ($filename, $rename_method, $no_suffix) = @_;
1133
1134 if(!$filename) { # undefined or empty string
1135 return $filename;
1136 }
1137
1138 if (!$rename_method) {
1139 print STDERR "WARNING: no file renaming method specified. Defaulting to using URL encoding...\n";
1140 # Debugging information
1141 my ($cpackage,$cfilename,$cline,$csubr,$chas_args,$cwantarray) = caller(1);
1142 print STDERR "Called from method: $cfilename:$cline $cpackage->$csubr\n";
1143 $rename_method = "url";
1144 } elsif($rename_method eq "none") {
1145 return $filename; # would have already been renamed
1146 }
1147
1148 # No longer replace spaces with underscores, since underscores mess with incremental rebuild
1149 ### Replace spaces with underscore. Do this first else it can go wrong below when getting tailname
1150 ###$filename =~ s/ /_/g;
1151
1152 my ($tailname,$dirname,$suffix);
1153 if($no_suffix) { # given a tailname, no suffix
1154 ($tailname,$dirname) = File::Basename::fileparse($filename);
1155 }
1156 else {
1157 ($tailname,$dirname,$suffix) = File::Basename::fileparse($filename, "\\.(?:[^\\.]+?)\$");
1158 }
1159 $suffix = "" if !$suffix;
1160
1161 if ($rename_method eq "url") {
1162 $tailname = &unicode::url_encode($tailname);
1163 }
1164 elsif ($rename_method eq "base64") {
1165 $tailname = &unicode::base64_encode($tailname);
1166 $tailname =~ s/\s*//sg; # for some reason it adds spaces not just at end but also in middle
1167 }
1168
1169 $filename = "$tailname$suffix";
1170 $filename = "$dirname$filename" if ($dirname ne "./" && $dirname ne ".\\");
1171
1172 return $filename;
1173}
1174
1175
1176# BACKWARDS COMPATIBILITY: Just in case there are old .ldb/.bdb files
1177sub rename_ldb_or_bdb_file {
1178 my ($filename_no_ext) = @_;
1179
1180 my $new_filename = "$filename_no_ext.gdb";
1181 return if (-f $new_filename); # if the file has the right extension, don't need to do anything
1182 # try ldb
1183 my $old_filename = "$filename_no_ext.ldb";
1184
1185 if (-f $old_filename) {
1186 print STDERR "Renaming $old_filename to $new_filename\n";
1187 rename ($old_filename, $new_filename)
1188 || print STDERR "Rename failed: $!\n";
1189 return;
1190 }
1191 # try bdb
1192 $old_filename = "$filename_no_ext.bdb";
1193 if (-f $old_filename) {
1194 print STDERR "Renaming $old_filename to $new_filename\n";
1195 rename ($old_filename, $new_filename)
1196 || print STDERR "Rename failed: $!\n";
1197 return;
1198 }
1199}
1200
1201
1202# Returns the greenstone URL prefix extracted from the appropriate GS2/GS3 config file.
1203# By default, /greenstone3 for GS3 or /greenstone for GS2.
1204sub get_greenstone_url_prefix() {
1205 # if already set on a previous occasion, just return that
1206 # (Don't want to keep repeating this: cost of re-opening and scanning files.)
1207 return $ENV{'GREENSTONE_URL_PREFIX'} if($ENV{'GREENSTONE_URL_PREFIX'});
1208
1209 my ($configfile, $urlprefix, $defaultUrlprefix);
1210 my @propertynames = ();
1211
1212 if($ENV{'GSDL3SRCHOME'}) {
1213 $defaultUrlprefix = "/greenstone3";
1214 $configfile = &util::filename_cat($ENV{'GSDL3SRCHOME'}, "packages", "tomcat", "conf", "Catalina", "localhost", "greenstone3.xml");
1215 push(@propertynames, qw/path\s*\=/);
1216 } else {
1217 $defaultUrlprefix = "/greenstone";
1218 $configfile = &util::filename_cat($ENV{'GSDLHOME'}, "cgi-bin", "gsdlsite.cfg");
1219 push(@propertynames, (qw/\nhttpprefix/, qw/\ngwcgi/)); # inspect one property then the other
1220 }
1221
1222 $urlprefix = &extract_propvalue_from_file($configfile, \@propertynames);
1223
1224 if(!$urlprefix) { # no values found for URL prefix, use default values
1225 $urlprefix = $defaultUrlprefix;
1226 } else {
1227 #gwcgi can contain more than the wanted prefix, we split on / to get the first "directory" level
1228 $urlprefix =~ s/^\///; # remove the starting slash
1229 my @dirs = split(/(\\|\/)/, $urlprefix);
1230 $urlprefix = shift(@dirs);
1231
1232 if($urlprefix !~ m/^\//) { # in all cases: ensure the required forward slash is at the front
1233 $urlprefix = "/$urlprefix";
1234 }
1235 }
1236
1237 # set for the future
1238 $ENV{'GREENSTONE_URL_PREFIX'} = $urlprefix;
1239# print STDERR "*** in get_greenstone_url_prefix(): $urlprefix\n\n";
1240 return $urlprefix;
1241}
1242
1243
1244# Given a config file (xml or java properties file) and a list/array of regular expressions
1245# that represent property names to match on, this function will return the value for the 1st
1246# matching property name. If the return value is undefined, no matching property was found.
1247sub extract_propvalue_from_file() {
1248 my ($configfile, $propertynames) = @_;
1249
1250 my $value;
1251 unless(open(FIN, "<$configfile")) {
1252 print STDERR "extract_propvalue_from_file(): Unable to open $configfile. $!\n";
1253 return $value; # not initialised
1254 }
1255
1256 # Read the entire file at once, as one single line, then close it
1257 my $filecontents;
1258 {
1259 local $/ = undef;
1260 $filecontents = <FIN>;
1261 }
1262 close(FIN);
1263
1264 foreach my $regex (@$propertynames) {
1265 ($value) = $filecontents=~ m/$regex\s*(\S*)/s; # read value of the property given by regex up to the 1st space
1266 if($value) {
1267 $value =~ s/^\"//; # remove any startquotes
1268 $value =~ s/\".*$//; # remove the 1st endquotes (if any) followed by any xml
1269 last; # found value for a matching property, break from loop
1270 }
1271 }
1272
1273 return $value;
1274}
1275
1276
12771;
Note: See TracBrowser for help on using the repository browser.